Home > Archives > Oracle 自动备份脚本

Oracle 自动备份脚本

Publish:

rem ---------------------------------------------------------------------------
rem windows环境下Oracle数据库的自动备份脚本。
rem 可以将本批处理设成windows任务计划下自动执行。
@echo on
@echo ================================================
@echo  windows环境下Oracle数据库的自动备份脚本
@echo  说明:启动备份时,需要配置以下变量
@echo    1、BACKUP_DIR           指定要备份到哪个目录
@echo    2、ORACLE_USERNAME      指定备份所用的Oracle用户名
@echo    3、ORACLE_PASSWORD      指定备份所用的Oracle密码
@echo    4、ORACLE_DB            指定备份所用的Oracle连接名
@echo    5、BACK_OPTION          备份选项,可以为空,可以为full=y,可以为owner=a用户,b用户  等等....
@echo    6、RAR_CMD              指定RAR命令行压缩工具所在目录
@echo ================================================
rem 以下变量需要根据实际情况配置------> 注意:此脚本必须放在E:\backup目录下
set BACKUP_DIR=D:\backup\data
set ORACLE_USERNAME=abc
set ORACLE_PASSWORD=123456
set ORACLE_DB=orcl
set BACK_OPTION= OWNER=abc
set RAR_CMD="D:\Program Files\WinRAR\Rar.exe"
set hh=%time:~0,2%
if /i %hh% LSS 10 (set hh=0%time:~1,1%)
set TODAY=%date:~0,4%-%date:~5,2%-%date:~8,2%_%hh%_%time:~3,2%_%time:~6,2%
set BACK_NAME=%ORACLE_DB%_%TODAY%_
set BACK_FULL_NAME=%BACKUP_DIR%\%BACK_NAME%
rem starting backup
exp %ORACLE_USERNAME%/%ORACLE_PASSWORD%@%ORACLE_DB%  %BACK_OPTION% file="%BACK_FULL_NAME%.dmp" log="%BACK_FULL_NAME%exp.log"
rem 压缩并删除原有文件
%RAR_CMD% a -df "%BACK_FULL_NAME%back.rar" "%BACK_FULL_NAME%.dmp" "%BACK_FULL_NAME%exp.log"
rem -----------------自动删除30天前的文件------------------
forfiles /m *.rar -d -30 /c "cmd /c del /f @path"  

声明: 本文采用 BY-NC-SA 授权。转载请注明转自: Ding Bao Guo